$!========================================================================
$!
$! Name      : COMPILE_TRGMON
$!
$! Purpose   : Do the compilation of all modules involved in TRGMON
$!
$! Arguments : [optional] P1 argument for pipe (e.g. SINCE=TODAY)
$!
$! Control   : [optional] define symbol $ deb = "DEB_" to make DEBUG objects 
$!                        $ DEASSIGN/SYMBOL DEB to return to no debug
$!
$! Created  15-MAR-1991   MICHIGAN STATE UNIVERSITY, TRIGGER CONTROL SOFTWARE
$! Modified 11-FEB-1994   Philippe Laurens - MSU L1 Trigger 
$!                          add optional qualifier for pipe selection
$!
$!========================================================================
$   ON ERROR     THEN $ GOTO EXIT
$   ON CONTROL_Y THEN $ GOTO EXIT
$   
$   @AUTO_DEF_LOCAL.COM
$   CD SHTRGMON:
$   
$   IF ( "''deb'" .EQS. "DEB_" ) THEN comp_option = "/DEBUG=ALL/NOOP" 
$   pipe_dir_qual = ""
$   IF ( P1 .NES. "" ) THEN pipe_dir_qual = "/" + P1
$   
$   IF ( F$SEARCH("''deb'TRGMON.OLB") .EQS. "" )  -
        THEN LIBRARY/CREATE/OBJECT 'deb'TRGMON.OLB
$
$   IF ( F$TRNLNM("trgmonop")      .NES. "" ) THEN DEASSIGN trgmonop
$   IF ( F$TRNLNM("trgmond")       .NES. "" ) THEN DEASSIGN trgmond
$   IF ( F$TRNLNM("trgmon_driver") .NES. "" ) THEN DEASSIGN trgmon_driver
$   TRGMON :== @HTRGMON:RUN_TRGMON
$
$   PIPE SET NOCONTINUE
$   PIPE SET NOLIS
$   
$   PIPE MENDIRECT *.SET'pipe_dir_qual'
$   IF ( F$SEARCH("*.MENU") .NES. "" ) THEN RENAME *.MENU HTRGMON:
$   
$   IF ( F$SEARCH("*.OBJ") .NES. "" ) THEN DELETE/NOCONF/NOLOG *.OBJ.*
$   PIPE FOR'comp_option' *.FOR'pipe_dir_qual' 
$   
$   LIB/REPL 'deb'TRGMON.OLB *.OBJ
$   IF ( F$SEARCH("*.OBJ") .NES. "" ) THEN DELETE/NOCONF/NOLOG *.OBJ.*
$   
$   IF ( F$SEARCH("*;-1") .NES. "" ) THEN PURGE/NOCONF/NOLOG 
$
$   LIBRARY/EXTRACT=SPAWN_TRGMON/OUT=SPAWN_TRGMON.OBJ 'deb'TRGMON.OLB
$   RENAME SPAWN_TRGMON.OBJ HTRGMON:
$   
$EXIT:
$   ON ERROR     THEN EXIT
$   CD HTRGMON:
$   PURGE/NOCONF/NOLOG 
$   WRITE SYS$OUTPUT "-Done-"
$   EXIT