$!========================================================================
$!
$! Name      : SHOWCASE_TRGMON_D0HSB
$!
$! Purpose   : Run TRGMON from the D0::TRGMGR account every 10 mn 
$!             to grab a screenful and send it to MSUHEP::LTA2110:
$!
$! Related Files: The directory used is the regular HTRGMON:
$!                             i.e. MSUTRGROOT:[TRG_HOST.SOURCE_TRGMON]
$!                SHOWCASE_TRGMON.LOG SHOWCASE_TRGMON.LIS are temporary files
$!                TRGMON_MAIN.EXE and TRGMON_DRIVER.EXE 
$!                TRGMOND.MENU and TRGMONOP.MENU are the compack menus 
$!                TRGMON_FS.RCP defines the foreign scaler labels 
$!                TRIGGER_RESOURCES.RCP defines the andor terms
$!                
$! Created   9-MAR-1993   Philippe Laurens
$!
$!========================================================================
$   ON ERROR     THEN $ GOTO error 
$   ON CONTROL_Y THEN $ GOTO EXIT
$
$! define symbols and logicals
$   @   SYS$LOGIN:TRIGGER_GENERAL.COM
$   IF ( F$MODE() .EQS. "INTERACTIVE" ) THEN     CLS
$   @   SYS$LOGIN:TRIGGER_SITE.COM
$   @   SYS$LOGIN:TRIGGER_LOGICALS.COM
$
$! destination of TRGMON screenful, LAT port assigned to VT240 in rack outside
$! of the elcetronic shop
$  lat_port = "FNBIT::MSUHEP::LTA2110:"
$  
$! define some implicit arguments to TRGMON
$ DEF MPOOL_CHANNEL REM_MPOOL
$ DEF TRGMON_DRIVER HTRGMON:TRGMON_DRIVER.EXE
$ DEF TRGMOND  HTRGMON:TRGMOND.MENU
$ DEF TRGMONOP HTRGMON:TRGMONOP.MENU
$ DEFINE TRGMON_RESOURCE ONLINE:[COOR_EXEC]TRIGGER.RES
$ DEFINE TRGMON_FS_RCP HTRGMON:TRGMON_FS.RCP
$ DEFINE FOR003  NL0:
$
$! define a symbol to run TRGMON and be able to use qualifier
$ TRGMON:=$HTRGMON:TRGMON_MAIN
$
$  bell[0,8]=7
$  esc[0,8]=27
$ 
$again:
$ TRGMON/COM=SHOWCASE_TRGMON.INP
$ 
$ OPEN/READ  input  SHOWCASE_TRGMON.LOG
$ OPEN/WRITE output SHOWCASE_TRGMON.LIS
$ 
$!skip the first 3 lines
$ READ/END=done  input line
$ READ/END=done  input line
$ READ/END=done  input line
$ 
$!edit the 4th line to add a ClearScreen and remove some characters to avoid 
$!wrapping screen lines. The terminal cannot be allocated and thus not modified
$!to have the /NOWRAP attribute.
$ READ/END=done  input line
$ write output esc+"[1;1H" + esc+"[2J" + F$extract(7,2000,line)
$ 
$!copy the rest of the file
$next_line:
$ READ/END=done  input line
$ WRITE output line
$ GOTO next_line

$done:
$ CLOSE input
$ CLOSE output
$ TYPE SHOWCASE_TRGMON.LIS 
$ COPY SHOWCASE_TRGMON.LIS 'lat_port' 
$ WAIT 00:05:00
$ COPY SHOWCASE_TRGMON.LIS 'lat_port' 
$ WAIT 00:05:00
$ DELETE/NOCONF SHOWCASE_TRGMON.LIS;*,SHOWCASE_TRGMON.LOG;*
$ GOTO again

$error:
$ IF ( F$TRNLNM("input")  .NES. "" ) THEN CLOSE input
$ IF ( F$TRNLNM("output") .NES. "" ) THEN CLOSE output
$ WRITE SYS$OUTPUT bell+bell+bell
$ WRITE SYS$OUTPUT bell+bell+bell
$ WAIT 00:05:00
$ GOTO again

$EXIT:
$ IF ( F$TRNLNM("input")  .NES. "" ) THEN CLOSE input
$ IF ( F$TRNLNM("output") .NES. "" ) THEN CLOSE output