SUBROUTINE DRAW_GEO_SECT()
C----------------------------------------------------------------------
C-
C-   Purpose and Methods : Draw the foreground of the Allocated Geographic
C-      Sections monitoring screen.
C-
C-   Inputs  : common block variables
C-   Outputs : screen output
C-   Controls: none
C-
C-   Created  31-JAN-1991   MICHIGAN STATE UNIVERSITY, TRIGGER CONTROL SOFTWARE
C-   Updated  30-APR-1992   Philippe Laurens, Steven Klocek  
C-              Add new items. 
C-
C----------------------------------------------------------------------
      IMPLICIT NONE
      INCLUDE 'LV1_MPOOL.PARAMS'
      INCLUDE 'LV1_MPOOL_DERIVED.INC'
      INCLUDE 'LV1_MPOOL_FORMATTED.INC'
      INCLUDE 'LV1_MON_SCREEN.INC'
      INCLUDE 'LV1_MON_SCREEN_LAYOUT.PARAMS'
C
      CHARACTER*132 BUFFER
      INTEGER GEO_SECT
      INTEGER COUNT
      INTEGER SECT_COUNT
C
C
C
      CALL RESET_LIST()
C
C       Draw top portion of screen
C
      CALL DRAW_GLOBAL_HEADER()
C
C       Print info on each allocated geographic section
C
      CALL SETSCROLL(GS_ALLOC_START_L, LINES-1)
      CALL PUT_STRING(GS_ALLOC_START_L, 1, ' ')
      SECT_COUNT = 0
      DO GEO_SECT = GEO_NUM_MIN, GEO_NUM_MAX
        BUFFER = '    |         |          |     |          '
     &    // '|           |           |'
C       16-APR-1991 add filter out geosect not used by any spec trig
C       -----------
        IF ( ( GEO_SECT_DATA(GEO_SECT).ALLOCATED .EQV. .TRUE. ) 
     &  .AND. ( ( GEO_SECT_DATA(GEO_SECT).NUM_TRG_FEB .NE. 0 )
     &     .OR. ( GEO_SECT_DATA(GEO_SECT).NUM_TRG_STD .NE. 0 ) ) )
     &  THEN
C
          SECT_COUNT = SECT_COUNT +1
          CALL INTTOSTR(GEO_SECT, BUFFER(GS_SEC_NUM_C:GS_SEC_NUM_E), 1)
          CALL BUILD_REAL_STRING(GEOSECT_ST_DIGITIZE_RATE(GEO_SECT), 2,
     &      BUFFER(GS_STD_RATE_C:GS_STD_RATE_E))
C
          IF (GEO_SECT_DATA(GEO_SECT).ST_DIG_STATE .EQV. .TRUE.) THEN
            BUFFER(GS_STD_EVENT_C:GS_STD_EVENT_E) = 
     &        '        T '
          ELSE
            BUFFER(GS_STD_EVENT_C:GS_STD_EVENT_E) = 
     &        '        F '
          ENDIF
C
          CALL BUILD_PERCENT_STRING(
     &      GEO_SECT_DATA(GEO_SECT).FE_BUSY_PERCENT,
     &      1, BUFFER(GS_FEB_PERCENT_C:GS_FEB_PERCENT_E) )
C
          IF (GEO_SECT_DATA(GEO_SECT).FE_BUSY_STATE .EQV. .TRUE.) THEN
            BUFFER(GS_FEB_EVENT_C:GS_FEB_EVENT_E) = 
     &        '        T '
          ELSE
            BUFFER(GS_FEB_EVENT_C:GS_FEB_EVENT_E) = 
     &        '        F '
          ENDIF
C
          CALL INTTOSTR(GEO_SECT_DATA(GEO_SECT).NUM_TRG_FEB,
     &      BUFFER(GS_SPTRG_FEB_C:GS_SPTRG_FEB_E), 1)
C
          CALL INTTOSTR(GEO_SECT_DATA(GEO_SECT).NUM_TRG_STD,
     &      BUFFER(GS_SPTRG_STD_C:GS_SPTRG_STD_E), 1)
C
          IF (GEO_SECT_DATA(GEO_SECT).STATUS .EQ. 
     &      GEO_SECT_STATUS_TEST) THEN
            BUFFER(GS_SPECIAL_C:GS_SPECIAL_E) = 'St.Dig.Off'
          ENDIF
C
          CALL PUT_STRING(PS_LIST, 0, BUFFER(1:79))
        ENDIF
      END DO
C
      CALL PUT_LIST(GS_ALLOC_START_L, 1)
C
      CALL MOVE_CURSOR_SAFE()
C
      CALL FLUSH_SCREEN()
C----------------------------------------------------------------------
  999 RETURN
      END