SUBROUTINE DRAW_REF_SET(SET_TYPE, SET_NUMBER)
C----------------------------------------------------------------------
C-
C-   Purpose and Methods : Draws the Reference Set monitoring screen.
C-
C-   Inputs  : Common block variables
C-   Outputs : Screen output
C-   Controls: SET_TYPE    What kind of reference set (EM ET, TOT ET...)
C-                      One of: RS_EM_ET, RS_TOT_ET
C-             SET_NUMBER  The reference set number
C-
C-   Created   9-JAN-1991   MICHIGAN STATE UNIVERSITY, TRIGGER CONTROL SOFTWARE
C-   Updated  30-APR-1992   Philippe Laurens, Steven Klocek  
C-              Handle out of range values as NO CONTRIBUTION. 
C-   Updated   2-SEP-1992   Philippe Laurens, Steven Klocek  
C-              Modularize so that other displays can utilize the
C-              symmetry-finding code.
C-   Updated   3-SEP-1993   Philippe Laurens - MSU L1 Trigger  
C-              Add Large Tiles 
C-
C----------------------------------------------------------------------
      IMPLICIT NONE
      INCLUDE 'LV1_MPOOL.PARAMS'
      INCLUDE 'LV1_MPOOL_DERIVED.INC' 
      INCLUDE 'LV1_MON_SCREEN.INC'
      INTEGER TRULEN
      EXTERNAL TRULEN
      EXTERNAL DRAW_REF_SYMMETRY_VALUE
      EXTERNAL DRAW_REF_SYMMETRY_OUT
C
      INTEGER SET_TYPE, SET_NUMBER
      INTEGER LENGTH
      CHARACTER*200 BUFFER
      LOGICAL SYMMETRIC_SIGN
      INTEGER ISTAT
C
C       Reset margins and clear screen
C
      CALL RESET_LIST()
      CALL SETSCROLL(3, LINES)
      CALL DRAW_REF_SYMMETRY_INIT
C
C       Print Headers
C
      IF (SET_TYPE .NE. RS_LGTILE) THEN
        BUFFER = 'Programming of Calorimeter ' // 
     &           'Trigger Tower Reference Set'
      ELSE 
        BUFFER = 'Programming of Calorimeter ' // 
     &           'Trigger Large Tile Reference Set'
      END IF      
      BUFFER(62:79) = CURRENT_TIME
      LENGTH = TRULEN(BUFFER)
      CALL PUT_STRING(1,1, BUFFER(1:LENGTH))
C
      BUFFER = ' '
      IF (SET_TYPE .EQ. RS_EM_ET) THEN
        BUFFER = 'EM Et  Ref Set # '
      ELSE IF (SET_TYPE .EQ. RS_TOT_ET) THEN
        BUFFER = 'TOT Et Ref Set # '
      ELSE 
        BUFFER = 'Large Tile Ref Set # '
      ENDIF
      CALL INTTOSTR(SET_NUMBER, BUFFER(22:22), 1)
      LENGTH = TRULEN(BUFFER)
      CALL PUT_STRING(3,1,BUFFER(1:LENGTH))
C       
C       Write out the symmetry
C
      CALL DRAW_TOWER_SYMMETRY(SET_NUMBER, SET_TYPE,
     &  DRAW_REF_SYMMETRY_VALUE, DRAW_REF_SYMMETRY_OUT)
C
      CALL PUT_LIST(5,1)
      CALL MOVE_CURSOR_SAFE()
      CALL FLUSH_SCREEN()
C----------------------------------------------------------------------
  999 CONTINUE
      RETURN
      END