SUBROUTINE DRAW_REF_SYMMETRY_VALUE(SIGN_ETA, MAGN_ETA, PHI, 
     &                                   RS_NUM, TYPE, 
     &                                   VALUE_1, VALUE_2 )
C----------------------------------------------------------------------
C-
C-   Purpose and Methods : Return the desired value from the array TT_THRSH. 
C-
C-   Inputs  : SIGN_ETA
C-             MAGN_ETA
C-             PHI         The Trigger Tower coordinates
C-             RS_NUM      The Reference Set number
C-             TYPE        The Ref Set type (RS_EM_ET, RS_TOT_ET, or RS_LGTILE)
C-   Outputs : VALUE_1     The value for the EM or TOT or Large Tile threshold.
C-             VALUE_2     The value for the HD Veto, or 0 
C-   Controls: none
C-
C-   Created   2-SEP-1992   Philippe Laurens, Steven Klocek
C-   Updated   3-SEP-1993   Philippe Laurens - MSU L1 Trigger  
C-                        replace argument names to values_1, value_2
C-                        get rid of USE_TOT on value_2 to flag tot_et
C-                        add Large Tiles.
C-
C----------------------------------------------------------------------
      IMPLICIT NONE
C
      INTEGER SIGN_ETA, MAGN_ETA, PHI, RS_NUM, TYPE
      INTEGER VALUE_1, VALUE_2
C
      INCLUDE 'LV1_MPOOL.PARAMS'
      INCLUDE 'LV1_MPOOL_DERIVED.INC' 
      INCLUDE 'LV1_MON_SCREEN.INC'
      INCLUDE 'LV1_MON_SCREEN_LAYOUT.PARAMS'
      INCLUDE 'LV1_MPOOL_RAW.INC'
C
      INTEGER HIGH_THRESH
      INTEGER MAX_VALID_EM, MAX_VALID_TOT, MAX_VALID_LT
      PARAMETER (HIGH_THRESH   = 10000 * 1000) 
      PARAMETER (MAX_VALID_EM  = 255/4 * 1000, 
     &           MAX_VALID_TOT = 255/2 * 1000,
     &           MAX_VALID_LT  = 32*255/4 * 1000 ) 
C
      VALUE_1 = 0 
      VALUE_2 = 0
C
      IF      (TYPE .EQ. RS_EM_ET) THEN
        VALUE_1
     &      = TT_THRSH(PHI, MAGN_ETA, SIGN_ETA, RS_NUM, RS_EM_ET)
        VALUE_2 
     &      = TT_THRSH(PHI, MAGN_ETA, SIGN_ETA, RS_NUM, RS_HD_VETO)
C
      ELSE IF (TYPE .EQ. RS_TOT_ET) THEN
        VALUE_1 
     &      = TT_THRSH(PHI, MAGN_ETA, SIGN_ETA, RS_NUM, RS_TOT_ET)
C
      ELSE IF (TYPE .EQ. RS_LGTILE) THEN 
        VALUE_1 = LT_THRSH( (PHI-1)/PHI_PER_LT+1, 
     &                       (MAGN_ETA-1)/ETA_PER_LT+1, 
     &                        SIGN_ETA, 
     &                        RS_NUM ) 
C
      ENDIF
C
      IF      (TYPE .EQ. RS_EM_ET) THEN
        IF (VALUE_1 .GE. MAX_VALID_EM)  VALUE_1 = HIGH_THRESH
        IF (VALUE_2 .GE. MAX_VALID_EM)  VALUE_2 = HIGH_THRESH
C
      ELSE IF (TYPE .EQ. RS_TOT_ET) THEN
        IF (VALUE_1 .GE. MAX_VALID_TOT) VALUE_1 = HIGH_THRESH
C
      ELSE IF (TYPE .EQ. RS_LGTILE) THEN 
        IF (VALUE_1 .GE. MAX_VALID_LT)  VALUE_1 = HIGH_THRESH
C
      ENDIF
C
C----------------------------------------------------------------------
  999 RETURN
      END