SUBROUTINE DERIVE_ADC_RATIOS ( )
C----------------------------------------------------------------------
C-
C-   Purpose and Methods :      build the variable ADC_CNT_VS_RAW_E which is
C-                              the ratio of ADC count over energy deposited in
C-                              a trigger tower.
C-                              It is computed as the product of the Input
C-                              energy error by the analog scaling factor of
C-                              the incoming signal divided by the ADC scale.
C-                              If local rescaling is performed, the analog
C-                              scaling factor already takes it into acoount. 
C-
C-   Inputs  :                  common block level1_lookup.inc
C-
C-   Created  31-JUL-1990   MICHIGAN STATE UNIVERSITY, TRIGGER CONTROL SOFTWARE
C-
C----------------------------------------------------------------------
      IMPLICIT     NONE 
C      
      INCLUDE     'D0$LEVEL1:LEVEL1_LOOKUP.PARAMS'
      INCLUDE     'D0$LEVEL1:LEVEL1_LOOKUP.INC'
C
      INTEGER      SIGN_ETA, MAGN_ETA, PHI
C
C----------------------------------------------------------------------
C
      DO PHI = PHI_MIN, PHI_MAX
       DO MAGN_ETA = ETA_MIN, ETA_MAX
        DO SIGN_ETA = POS_ETA, NEG_ETA
C
          ADC_CNT_VS_RAW_E (SIGN_ETA,MAGN_ETA,PHI,EM_TOWER) = 
     &          ANALOG_INPUT_SCALING (SIGN_ETA,MAGN_ETA,PHI,EM_TOWER)
     &        * ( ( INPUT_ENERGY_ERROR (SIGN_ETA,MAGN_ETA,PHI,EM_TOWER)
     &            / 100.0 ) + 1.0 )
     &        / GLOBAL_ADC_SCALE
          ADC_CNT_VS_RAW_E (SIGN_ETA,MAGN_ETA,PHI,HD_TOWER) = 
     &          ANALOG_INPUT_SCALING (SIGN_ETA,MAGN_ETA,PHI,HD_TOWER)
     &        * ( ( INPUT_ENERGY_ERROR (SIGN_ETA,MAGN_ETA,PHI,HD_TOWER)
     &            / 100.0 ) + 1.0 )
     &        / GLOBAL_ADC_SCALE
C       for the total tower, take half of the average of EM and HD.
C       This atrtifical number is used to calculate the component of the cut
C       due to electronics noise.
          ADC_CNT_VS_RAW_E (SIGN_ETA,MAGN_ETA,PHI,TOT_TOWER) = 
     &      ( ADC_CNT_VS_RAW_E (SIGN_ETA,MAGN_ETA,PHI,EM_TOWER) 
     &      + ADC_CNT_VS_RAW_E (SIGN_ETA,MAGN_ETA,PHI,HD_TOWER) )
     &      / 2.0 / 2.0 
        END DO
       END DO
      END DO
C
C----------------------------------------------------------------------
  999 RETURN
      END
C