FUNCTION   LUQ_VS_ET ( SIGN_ETA, MAGN_ETA, PHI, CHANNEL )
C----------------------------------------------------------------------
C-
C-   Purpose and Methods :  Collection of functions building the final prom
C-                          output quantities from the input Et energies.
C-                          This routine has several entry points:
C-                          ET_VS_ET = no transformation
C-                          E_VS_ET  = return to deposited energy
C-                          PX_VS_ET = projection along the X-axis
C-                          PY_VS_ET = projection along the Y-axis
C-
C-   Inputs  :              SIGN_ETA, MAGN_ETA, PHI = trigger tower coordinates
C-                          CHANNEL = EM_TOWER, HD_TOWER, or TOT_TOWER
C-                          Not all arguments are used by all sub-functions.
C-                          Common block level1_lookup.inc
C-
C-   Outputs :              Projection ratio to go from Et to the various
C-                          prom output quantities
C-
C-   Created   6-AUG-1990 MICHIGAN STATE UNIVERSITY, TRIGGER CONTROL SOFTWARE
C-
C----------------------------------------------------------------------
      IMPLICIT NONE
C
      INCLUDE     'D0$PARAMS:LEVEL1_LOOKUP.PARAMS'
      INCLUDE     'D0$INC:LEVEL1_LOOKUP.INC'
      INCLUDE 'LSMP$SOURCE:LEVEL1_LOOKUP_EXPANSION.INC'
C
      INTEGER    SIGN_ETA, MAGN_ETA, PHI, CHANNEL
      REAL       LUQ_VS_ET, ET_VS_ET, E_VS_ET, PX_VS_ET, PY_VS_ET
      REAL       TWR_R, TWR_Z, SIN_THETA_0
C
C     This function is only used via explicit entry points
C
      RETURN
C----------------------------------------------------------------------
      ENTRY      ET_VS_ET ( SIGN_ETA, MAGN_ETA, PHI, CHANNEL )
C
      ET_VS_ET = 1.
C
      RETURN
C
C----------------------------------------------------------------------
      ENTRY      E_VS_ET ( SIGN_ETA, MAGN_ETA, PHI, CHANNEL )
C
      TWR_R = TOWER_RZ_COORD(SIGN_ETA,MAGN_ETA,PHI,CHANNEL,R_COORD)
      TWR_Z = TOWER_RZ_COORD(SIGN_ETA,MAGN_ETA,PHI,CHANNEL,Z_COORD)
      SIN_THETA_0 = TWR_R / SQRT ( TWR_R**2 + TWR_Z**2 )
      E_VS_ET = 1. / SIN_THETA_0
C
      RETURN
C
C----------------------------------------------------------------------
      ENTRY      PX_VS_ET ( SIGN_ETA, MAGN_ETA, PHI, CHANNEL  )
C
      PX_VS_ET = ABS( COS ( 1.74533E-2
     &               * TOWER_PHI_COORD(SIGN_ETA,MAGN_ETA,PHI) ) )
C
      RETURN
C----------------------------------------------------------------------
      ENTRY      PY_VS_ET ( SIGN_ETA, MAGN_ETA, PHI, CHANNEL )
C
      PY_VS_ET = ABS( SIN ( 1.74533E-2
     &               * TOWER_PHI_COORD(SIGN_ETA,MAGN_ETA,PHI) ) )
C
      RETURN
C----------------------------------------------------------------------
      END