Yacht 400 Simulation #1
*
.WIDTH IN=72 OUT=80
.OPT NODE
*
*
* Power Supply for the JFET
*
VCC 18 0 5
*
*
* Sweep the input voltage from 1 MHz to 100 MHz in 100 steps.
*
.AC LIN 100 1MEGHz 100MEGHZ
*
*
* Voltage Source 500 Ohms
*
VIN 1 0 AC 1
RS1 1 2  500
*
*
* Input R and C
*
C1INPUT 2 3   220PF
R1INPUT 2 0    10K
*
*
* Input Shunt C+R||R+L
*
C1SHNT1   3 14   680PF
R1SHNT1  14 15    47
R2SHNT1   3 15   330
L1SHNT1  15  0    22UH
*
*
* Series Diode
*
D1SERS1  4  3   DMOD
*
*
* Second Shunt  L||R + C
*
R1SHNT2   4  16     4.7K
L1SHNT2   4  16      68UH
C1SHNT2  16   0   0.033UF
L2SHNT2  16  17      20MH
R2SHNT2  17  18       1K
*
*
* Third Shunt  C + R || L+C+R
*
C1SHNT3   4  19      47PF
R1SHNT3  19   0      10K
L1SHNT3  19  20     180UH
C2SHNT3  20  21      68PF
R2SHNT3  21   0     100
*
*
* Third Series  C
*
C1SERS3   4   5   220PF
*
*
* Fourth Series  L||C
*
L1SERS4   5  6    1UH
C1SERS4   5  6    3PF
*
*
* Fifth Series  L||C
*
L1SERS5   6  7   0.47UH
C1SERS5   6  7      5PF
*
*
* Series and Shunt R's
*
R1SERS6   7  8   100
R2SERS6   8  0    47k
*
*
* Source Follower JFET
*
JFET1  10  8  9   MOD1
*
*
* Drain Bypass Capacitors and Isolation Resistor
*
CBYPAS2   10   0    10UF
RDRAIN1   10  18   100
*
*
*
* Source Load LR Series Circuit
*
LSLOAD1  9  23  220UH
RSLOAD1 23   0   47
*
*
* Source Follower Output Coupling Capacitor and Inductor
*
CCOUPLE   9  11   0.033UF
LCOUPLE  11  12   0.47UH
*
*
* Shunt CLC  Circuit
*
C1SHNT4  12   0   82PF
L1SHNT4  12  13    1UH
C2SHNT4  13   0   68PF
*
*
*
* Load Measuring Resistor
*
RLOADM1  13  0   1K
*
*
*
*   Diode Model
*
.MODEL DMOD  D
*
*
*  JFET Model
*
.MODEL MOD1 NJF   VTO=-2.0    BETA=1.0E-3    LAMBDA=1.0E-4     PB=0.6
+                  RD=50        RS=50           CGS=5PF       CGD=1PF
*
*
*
*   Output Selection
*
.PRINT AC VM(13,0) VP(13,0)
.PLOT  AC VM(13,0) VP(13,0)
*
.END